             CHI-SQUARED DISTRIBUTION CRITICAL VALUE

Michael Lloyd (http://www.hsu.edu/faculty/lloydm/ti/prgmtabl.html)
Henderson State University

DESCRIPTION
Given the area under a chi-squared random probability density function,
the Critical value(s) are found.

INSTRUCTIONS
1. Enter the degrees of freedom.
2. Select the form of area you wish to enter, or quit the program. The
TAIL selections 1-3 are often used for hypothesis testing, and 
selection 4 is often used for confidence intervals.
  1. LEFT TAIL - area is from 0 to the critical value.
  2. RIGHT TAIL - area is from the critical value to infinity.
  3. 2-TAIL - area is the sum of the left and right tail areas. Two
     critcal values are found in this case.
  4. CONF. INTERVAL - area is in the middle and what is left over is
     split between the tails.
3. Enter the area. SIG stands for the signicance level alpha of the 
hypothesis   test; CONF LEVEL stands for confidence level c.
4. The critical value(s) will be displayed.

VERSION HISTORY
1.0 - December 1996 - original version called X2VAL
1.1 - March 2007 - added copyright
1.2 - August 2015 - updated file to .8xp

VARIABLES USED
C = area under pdf
K = degrees of freedom
prgmZZINEWT = subroutine
T = chi-squared value
X = independent variable of pdf
Y = chi-squared pdf

PROGRAM LISTING

Disp "VERSION 1.1","(C)2007 M LLOYD"
Input "DEG FREED=",K
"\chi\\^2\pdf(X,K)"\->\Y\0\
2\->\P
.001\->\Q
Menu("\chi\\^2\ DISTRIBUTION","LEFT TAIL",1,"RIGHT TAIL",2,"2-TAIL",3,"CONF. INTERVAL",4,"QUIT",5)
Lbl 1
Input "SIG.=",C
Disp "X\^2\="
prgmZZINEWT
Disp T
Goto 5:Lbl 2
Input "SIG.=",C
1-C\->\C
Disp "X\^2\="
prgmZZINEWT
Disp T
Goto 5:Lbl 3
Input "SIG.=",C
C/2\->\C
Disp "LEFT CRIT="
prgmZZINEWT
Disp T
1-C\->\C
Disp "RIGHT CRIT="
prgmZZINEWT
Disp T
Goto 5:Lbl 4
Input "CONF LEVEL=",C
(1-C)/2\->\C
Disp "LEFT PT="
prgmZZINEWT
Disp T
1-C\->\C
Disp "RIGHT PT="
prgmZZINEWT
Disp T
Lbl 5:DelVar Y\0\
